QML-тип FolderPickerDialog

Диалог для выбора пути к каталогу. Подробнее…

Строка импорта:

import Sailfish.Pickers 1.0

• Список всех членов класса, включая унаследованные

Свойства

• checkLengthPath : bool
• path : string
• selectedPath : string
• title : string

Подробное описание

Переменная path может использоваться для установки начального местоположения для выбора каталога.

Пример использования:

 import QtQuick 2.2
 import Sailfish.Silica 1.0
 import Sailfish.Pickers 1.0

 ApplicationWindow {
     initialPage: Component {
         Page {
             id: page

             property string directoryPath

             SilicaFlickable {
                 contentHeight: column.height + Theme.paddingLarge*2
                 anchors.fill: parent
                 VerticalScrollDecorator {}

                 Column {
                     id: column
                     width: parent.width
                     PageHeader {
                         title: "Пример выбора каталога"
                     }

                     ValueButton {
                         anchors.horizontalCenter: parent.horizontalCenter
                         label: "Каталог"
                         value: directoryPath ? directoryPath : "None"
                         onClicked: pageStack.push(folderPickerDialog)
                     }
                 }
             }

             Component {
                 id: folderPickerDialog

                 FolderPickerDialog {
                     title: "Скачать в"
                     onAccepted: directoryPath = selectedPath
                     onRejected: directoryPath = ""
                 }
             }
         }
     }
 }

Примечание: приложение должно иметь разрешение UserDirs, чтобы средство выбора работало корректно.

См. также MultiFilePickerDialog, MultiContentPickerDialog, MultiDocumentPickerDialog, MultiDownloadPickerDialog, MultiImagePickerDialog, MultiMusicPickerDialog и MultiVideoPickerDialog.

Описание свойств

checkLengthPath : bool

Если true, диалог выдаст страницу с сообщением об ошибке, когда размер пути превысит 4096 байт.

Значение по умолчанию: false.

path : string

Свойство содержит начальный путь для диалога выбора каталога.

По умолчанию начальный путь — это домашний каталог.

selectedPath : string

Свойство содержит путь к выбранному каталогу.

По умолчанию используется путь к домашнему каталогу пользователя.

title : string

Содержит название диалога. Текущий выбранный каталог отображается под заголовком.

По умолчанию значением заголовка является пустая строка.