QML-тип MultiFilePickerDialog

Средство выбора нескольких файлов. Подробнее…

Строка импорта:

import Sailfish.Pickers 1.0

• Список всех членов класса, включая унаследованные

Свойства

• nameFilters : list<string>
• selectedContent : ListModel
• title : string

Подробное описание

В примере ниже продемонстрирован выбор файлов с расширениями .pdf или .doc:

 import QtQuick 2.2
 import Sailfish.Silica 1.0
 import Sailfish.Pickers 1.0

 ApplicationWindow {
     initialPage: Component {
         Page {
             id: page

             property string selectedFiles

             SilicaFlickable {
                 contentHeight: column.height + Theme.paddingLarge*2
                 anchors.fill: parent
                 VerticalScrollDecorator {}

                 Column {
                     id: column
                     width: parent.width
                     PageHeader {
                         title: "Пример выбора нескольких файлов"
                     }

                     ValueButton {
                         anchors.horizontalCenter: parent.horizontalCenter
                         label: "Выгрузить документы"
                         value: selectedFiles ? selectedFiles : "Нет"
                         onClicked: pageStack.push(multiFilePickerDialog)
                     }
                 }
             }

             Component {
                 id: multiFilePickerDialog
                 MultiFilePickerDialog {
                     nameFilters: [ '*.pdf', '*.doc' ]

                     onAccepted: {
                         selectedFiles = ""
                         var urls = []
                         for (var i = 0; i < selectedContent.count; ++i) {
                             var url = selectedContent.get(i).url
                             // Обработка выгрузки URL
                             urls.push(selectedContent.get(i).url)
                         }
                         selectedFiles = urls.join(", ")
                     }

                     onRejected: selectedFiles = ""
                 }
             }
         }
     }
 }

Примечание: приложение должно иметь разрешение UserDirs, чтобы средство выбора работало корректно.

Примечание: разрешение RemovableMedia необязательно, оно позволяет просматривать файлы со съёмного носителя.

Для выбора одного файла следует использовать FilePickerPage.

См. также MultiContentPickerDialog, MultiDocumentPickerDialog, MultiDownloadPickerDialog, MultiImagePickerDialog, MultiMusicPickerDialog и MultiVideoPickerDialog.

Описание свойств

nameFilters : list<string>

Содержит список фильтров для имён файлов, которые доступны для данного средства выбора.

[read-only] selectedContent : ListModel

Содержит свойства выбранного файла.

selectedContentProperties включает в себя следующие поля:

• fileName — имя файла без пути;
• filePath — полный путь к файлу, включая его имя;
• url — значение поля filePath в формате URL;
• title — название файла, которое может быть получено из метаданных файла;
• mimeType — MIME-тип файла (например, "image/jpeg", "image/png", "application/pdf", "video/mp4", "audio/mpeg").

title : string

Содержит название диалога.

По умолчанию используется "Выбрать расположение" или перевод этой фразы.