QML-тип MultiContentPickerDialog

Диалог группирует средства выбора нескольких файлов. Подробнее…

Строка импорта:

import Sailfish.Pickers 1.0

• Список всех членов класса, включая унаследованные

Свойства

• acceptText : string
• selectedContent : ListModel
• title : string

Подробное описание

Тип MultiContentPickerDialog представляет собой диалог, с помощью которого можно выбрать несколько файлов различных типов, перечисленных ниже:

• Документы — файлы документов в каталоге /home/<user>/;
• Изображения — файлы изображений в каталоге /home/<user>/ за исключением стандартного каталога для музыки (/home/<user>/Music);
• Видео — видеофайлы в каталоге /home/<user>/;
• Музыка — файлы с музыкой в каталоге /home/<user>/.

Пример использования:

 import QtQuick 2.2
 import Sailfish.Silica 1.0
 import Sailfish.Pickers 1.0

 ApplicationWindow {
     initialPage: Component {
         Page {
             property string selectedFiles

             SilicaFlickable {
                 contentHeight: column.height + Theme.paddingLarge*2
                 anchors.fill: parent
                 VerticalScrollDecorator {}

                 Column {
                     id: column
                     width: parent.width
                     PageHeader {
                         title: "Пример выбора нескольких файлов с содержимым"
                     }

                     ValueButton {
                         anchors.horizontalCenter: parent.horizontalCenter
                         label: "Выгрузить файлы"
                         value: selectedFiles ? selectedFiles : "Нет"
                         onClicked: pageStack.push(multiDocumentPickerDialog)
                     }
                 }
             }

             Component {
                 id: multiDocumentPickerDialog
                 MultiDocumentPickerDialog {
                     title: "Выбрать файлы"
                     onAccepted: {
                         selectedFiles = ""
                         var urls = []
                         for (var i = 0; i < selectedContent.count; ++i) {
                             var url = selectedContent.get(i).url
                             // Обработка выгрузки URL
                             urls.push(selectedContent.get(i).url)
                         }
                         selectedFiles = urls.join(", ")
                     }

                     onRejected: selectedFiles = ""
                 }
             }
         }
     }
 }

Примечание: приложение должно иметь разрешения UserDirs и MediaIndexing, чтобы средство выбора работало корректно.

Примечание: разрешение RemovableMedia необязательно, оно позволяет просматривать файлы со съёмного носителя.

Для выбора одного файла следует использовать ContentPickerPage.

См. также MultiDocumentPickerDialog, MultiDownloadPickerDialog, MultiImagePickerDialog, MultiMusicPickerDialog, MultiVideoPickerDialog и ContentPickerPage.

Описание свойств

acceptText : string

Содержит текст, отображаемый в правой части заголовка.

[read-only] selectedContent : ListModel

Содержит свойства выбранных файлов.

Каждый элемент в ListModel содержит следующие поля:

• fileName — имя файла без пути;
• filePath — полный путь к файлу, включая его имя;
• url — значение поля filePath в формате URL;
• title — название файла, которое может быть получено из метаданных файла;
• mimeType — MIME-тип файла (например, "image/jpeg", "application/pdf", "video/mp4", "audio/mpeg").

title : string

Содержит заголовок страницы.

По умолчанию значением заголовка является пустая строка.