QML-тип MultiVideoPickerDialog

Средство выбора нескольких видеофайлов. Подробнее…

Строка импорта:

import Sailfish.Pickers 1.0

• Список всех членов класса, включая унаследованные

Свойства

• acceptText : string
• selectedContent : ListModel

Подробное описание

Пример использования:

 import QtQuick 2.2
 import Sailfish.Silica 1.0
 import Sailfish.Pickers 1.0

 ApplicationWindow {
     initialPage: Component {
         Page {
             property string selectedFiles

             SilicaFlickable {
                 contentHeight: column.height + Theme.paddingLarge*2
                 anchors.fill: parent
                 VerticalScrollDecorator {}

                 Column {
                     id: column
                     width: parent.width
                     PageHeader {
                         title: "Пример выбора нескольких видео"
                     }

                     ValueButton {
                         anchors.horizontalCenter: parent.horizontalCenter
                         label: "Выбрать видео файлы"
                         value: selectedFiles ? selectedFiles : "Нет"
                         onClicked: pageStack.push(multiVideoPickerDialog)
                     }
                 }
             }

             Component {
                 id: multiVideoPickerDialog
                 MultiVideoPickerDialog {
                     onAccepted: {
                         selectedFiles = ""
                         var urls = []
                         for (var i = 0; i < selectedContent.count; ++i) {
                             var url = selectedContent.get(i).url
                             // Обработка выбора
                             urls.push(selectedContent.get(i).url)
                         }
                         selectedFiles = urls.join(", ")
                     }

                     onRejected: selectedFiles = ""
                 }
             }
         }
     }
 }

Примечание: приложение должно иметь разрешения Videos и MediaIndexing, чтобы средство выбора работало корректно.

Для выбора одного видеофайла следует использовать тип VideoPickerPage.

См. также MultiContentPickerDialog, MultiDocumentPickerDialog, MultiDownloadPickerDialog, MultiFilePickerDialog, MultiImagePickerDialog и MultiMusicPickerDialog.

Описание свойств

acceptText : string

Содержит текст, отображаемый в правой части заголовка.

[read-only] selectedContent : ListModel

Содержит свойства выбранных файлов.

Каждый элемент в ListModel содержит следующие поля:

• fileName — имя файла без пути;
• filePath — полный путь к файлу, включая его имя;
• url — значение поля filePath в формате URL;
• title — название файла, которое может быть получено из метаданных файла;
• mimeType — MIME-тип файла (например, "image/jpeg", "application/pdf", "video/mp4", "audio/mpeg").