QML-тип FolderPickerPage

Средство для выбора каталога. Подробнее…

Строка импорта: import Sailfish.Pickers 1.0

Список всех членов класса, включая унаследованные

Свойства

checkLengthPath : bool
dialogTitle : string
selectedPath : string
showSystemFiles : bool
title : string

Подробное описание

FolderPickerDialog показывает сразу все точки монтирования.

Пример использования:

 import QtQuick 2.2
 import Sailfish.Silica 1.0
 import Sailfish.Pickers 1.0

 ApplicationWindow {
     initialPage: Component {
         Page {
             id: page

             property string directoryPath

             SilicaFlickable {
                 contentHeight: column.height + Theme.paddingLarge*2
                 anchors.fill: parent
                 VerticalScrollDecorator {}

                 Column {
                     id: column
                     width: parent.width
                     PageHeader {
                         title: "Пример выбора каталога"
                     }

                     ValueButton {
                         anchors.horizontalCenter: parent.horizontalCenter
                         label: "Каталог"
                         value: directoryPath ? directoryPath : "None"
                         onClicked: pageStack.push(folderPickerPage)
                     }
                 }
             }

             Component {
                 id: folderPickerPage
                 FolderPickerPage {
                     dialogTitle: "Скачать в"
                     onSelectedPathChanged: page.directoryPath = selectedPath
                 }
             }
         }
     }
 }

Примечание: приложение должно иметь разрешение UserDirs, чтобы средство выбора работало корректно.

Примечание: разрешение RemovableMedia необязательно, оно позволяет просматривать файлы со съёмного носителя.

См. также ContentPickerPage, DocumentPickerPage, ImagePickerPage, MusicPickerPage и VideoPickerPage.

Описание свойств

checkLengthPath : bool

Если true, страница выдаст сообщение об ошибке, когда размер пути превысит 4096 байт.

Значение по умолчанию: false.

dialogTitle : string

Содержит название диалога. Текущий выбранный каталог отображается под заголовком.

По умолчанию значением dialogTitle является пустая строка.

selectedPath : string

Свойство содержит путь к выбранному каталогу.

По умолчанию значением selectedPath является пустая строка.

showSystemFiles : bool

Устанавливает, может ли пользователь видеть корневой системный каталог.

Значение showSystemFiles по умолчанию: false.

title : string

Содержит заголовок страницы.

По умолчанию используется "Выбрать расположение" или перевод этой фразы.