PdfPrintHandler

Выдает результаты «сохранить как PDF» для расширения PdfPrintExtension. Подробнее…

Подключение:

#include <pdfprinthandler.h>

Диаграмма наследования для Aurora::WebView::PdfPrintHandler:

Пример выбора двух видов отступов:

import QtQuick 2.0
import Sailfish.Silica 1.0
import ru.auroraos.WebView 1.0
import ru.auroraos.WebView.Global 1.0

Page {
    id: page

    SilicaFlickable {
        anchors.fill: parent
        contentHeight: column.height

        Column {
            id: column

            anchors.fill: parent
            spacing: Theme.paddingLarge

            PageHeader {
                title: "Сохранить страницу как PDF"
            }

            // Установка пути к файлу
            TextField {
                id: filePath
                text: StandardPaths.documents + "/page.pdf"
            }

            Row {
                spacing: Theme.paddingLarge

                // Установка отступов
                Column {
                    Button {
                        id: margins
                        text: "Без отступов"

                        onClicked: {
                            pdfPrintExtension.marginType = pdfPrintExtension.marginType === PdfPrintMarginType.PDF_PRINT_MARGIN_NONE ? PdfPrintMarginType.PDF_PRINT_MARGIN_DEFAULT : PdfPrintMarginType.PDF_PRINT_MARGIN_NONE
                            margins.text = pdfPrintExtension.marginType === PdfPrintMarginType.PDF_PRINT_MARGIN_NONE ? "Без отступов": "Отступы по умолчанию"
                        }
                    }
                }

                Column {
                    // Выбор ориентации страницы
                    Button {
                        id: orientation
                        text: "Горизонтальная ориентация"

                        onClicked: {
                            pdfPrintExtension.landscape = !pdfPrintExtension.landscape
                            orientation.text = pdfPrintExtension.landscape ? "Горизонтальная ориентация" : "Вертикальная ориентация"
                        }
                    }
                }
            }

            // Установка масштаба
            TextField {
                id: scale
                text: ".8"
            }

            Button {
                anchors.horizontalCenter: parent.horizontalCenter
                text: "Сохранить как PDF"

                onClicked: {
                    // Установка масштаба
                    pdfPrintExtension.scale = scale.text
                    // Сохранение страницы в pdf
                    pdfPrintExtension.printToPdf(filePath.text)
                }
            }

            Label {
                id: output
                text: ""
                font.pixelSize: 22
            }

            WebView {
                id: webView

                PdfPrintExtension {
                    id: pdfPrintExtension

                    // Испускается сигнал pdfPrintResultAvailable. Доступны параметры path и result
                    onPdfPrintResultAvailable: {
                        output.text = result ? "Результат: PDF сохранён по пути " + filePath.text : "Результат: сохранить PDF не удалось"
                    }
                }

                width: parent.width
                height: page.height - webView.y
                url: "https://ya.ru/"
            }
        }
    }
}

Сигналы

void	pdfPrintResultAvailable (bool result, QString path) Испускается, когда доступен результат сохранения в формате PDF.

Публичные функции-члены

void	pdfPrintResult (const PdfPrintResult &pdfPrintResult) override

Статические публичные функции-члены

static QSharedPointer<PdfPrintHandler>

GetInstance (QQmlEngine *qmlEngine=nullptr, QJSEngine *jsEngine=nullptr) Cоздает (если не существует) и возвращает экземпляр PdfPrintHandler. Подробнее...

Подробное описание

Выдает результаты «сохранить как PDF» для расширения PdfPrintExtension.

Описание функций-членов

GetInstance()

static QSharedPointer<PdfPrintHandler> Aurora::WebView::PdfPrintHandler::GetInstance (QQmlEngine * qmlEngine = nullptr, QJSEngine * jsEngine = nullptr)

static

Создаёт (если не существует) и возвращает экземпляр PdfPrintHandler.

Возвращает экземпляр PdfPrintHandler.