QML-тип ViewPlaceholder

Текстовая метка, отображаемая в центре элемента, которая появляется в случае недоступности содержимого страницы. Подробнее…

Строка импорта:	`import Sailfish.Silica 1.0`
Наследуется от:	Text

Список всех членов класса, включая унаследованные

Свойства

enabled : bool
hintText : string
leftMargin : real
rightMargin : real
text : string
textFormat : real
verticalOffset : real

Подробное описание

Тип ViewPlaceholder отображает текстовую метку в пустых представлениях.

Текст, который содержится в свойствах text и hintText, отображается в центре представления, чтобы предоставить дополнительную информацию о состоянии пустого содержимого. Если представление имеет PullDownMenu, то нажатие на ViewPlaceholder откроет это меню, чтобы показать пользователю доступные действия.

Например:

import QtQuick 2.2
import Sailfish.Silica 1.0

ApplicationWindow {
    initialPage: Component {
        Page {
            SilicaListView {
                id: view
                anchors.fill: parent
                header: PageHeader { title: "Пример" }
                model: ListModel { id: listModel }

                delegate: BackgroundItem {
                    width: ListView.view.width
                    Label {
                        text: model.date
                        x: Theme.horizontalPageMargin
                        anchors.verticalCenter: parent.verticalCenter
                    }
                }

                ViewPlaceholder {
                    enabled: view.count == 0
                    text: "Нет элементов"
                    hintText: "Потяните вниз, чтобы добавить элементы"
                }

                PullDownMenu {
                    MenuItem {
                        text: "Добавить элемент"
                        onClicked: {
                            listModel.append({"date": new Date().toLocaleTimeString()})
                        }
                    }
                }
            }
        }
    }
}

Примечание. ViewPlaceholder должен иметь в своей родительской иерархии элемент одного из следующих типов: SilicaFlickable, SilicaListView, SilicaGridView или SilicaWebView.

Описание свойств

enabled : bool

Задание свойства в значение true вызывает отображение заполнителя.

hintText : string

Содержит текст, который размещается под основным текстом с дополнительной информацией о причинах отсутствия содержимого представления.

leftMargin : real

Содержит отступ между левым и правым краями заполнителя и его содержимым. Значение по умолчанию: Theme.horizontalPageMargin.

rightMargin : real

text : string

Свойство содержит основной текст заполнителя.

textFormat : real

Свойство определяет формат, используемый для отображения основного и дополнительного текстов. Значение по умолчанию: Text.PlainText.

verticalOffset : real

Определяет смещение по вертикали текста заполнителя.