QML-тип ApplicationWindow

Компонент верхнего уровня приложения ОС Аврора. Подробнее…

Строка импорта:	`import Sailfish.Silica 1.0`
Наследуется от:	SilicaControl

Свойства

allowedOrientations : enumeration
background.color : color (preliminary)
background.filter : string (preliminary)
background.image : url (preliminary)
background.material : string (preliminary)
background.wallpaper : var (preliminary)
bottomMargin : real
contentItem : Item
cover : var
defaultAllowedOrientations : enumeration
deviceOrientation : enumeration
displayMode : ApplicationDisplayMode
initialPage : var
orientation : enumeration
pageStack : PageStack
screenRotation : real
statusbarBackgroundColor : color
statusbarForceVisible : bool
statusbarOpacity : real
statusbarScheme : ColorScheme

Прикрепляемые свойства

SafeZoneRect : SafeZoneRect

Подробное описание

Тип ApplicationWindow используется для создания элемента верхнего уровня в приложении ОС Аврора.

Каждое приложение ОС Аврора должно иметь один компонент ApplicationWindow, определённый в корне его иерархии. Окно приложения — это точка входа для загрузки приложения.

Тип ApplicationWindow позволяет приложению:

управлять стеком страниц;
устанавливать активную обложку;
устанавливать фоновый рисунок;
обрабатывать изменения ориентации для обновления пользовательского интерфейса.

Самое простое окно приложения состоит из одной initialPage — страницы, которая отображается при открытии приложения:

import Sailfish.Silica 1.0

ApplicationWindow {
    initialPage: Component {
        Page {
            Text { <s7>text</s7>: "Привет!" }
        }
    }
}

Иерархическая навигация со стеком страниц приложения

Каждое окно приложения содержит один стек страниц, доступный через свойство pageStack, который определяет контент, отображаемый приложением. Стек состоит из объектов Page: каждая страница содержит контент, который будет отображаться приложением в определённый момент времени. Страница с контентом может быть добавлена (push) в стек или удалена (pop) из стека. Самая верхняя страница — это страница, которая последней была помещена в стек и которая в настоящее время отображается в окне приложения.

Ниже представлено простое приложение, которое изначально отображает страницу, содержащую единственную кнопку. Когда кнопка нажата, Page определённая как AnotherPage.qml помещается в стек и становится самой верхней страницей, отображаемой приложением:

// main.qml
import QtQuick 2.2
import Sailfish.Silica 1.0

ApplicationWindow {
    initialPage: Component {
        Page {
            Button {
                text: "Привет!"
                onClicked: pageStack.push("AnotherPage.qml")
            }
        }
    }
}

// AnotherPage.qml
import QtQuick 2.2
import Sailfish.Silica 1.0

Page {
    Button {
        text: "Закрыть эту страницу"
        onClicked: pageStack.pop()
    }
}

Получить дополнительную информацию об изменении стека страниц можно в документации PageStack.

Активные обложки: предоставление статуса приложения на главном экране

Для каждого приложения ОС Аврора может быть установлена собственная активная обложка через свойство cover. Активная обложка — это визуальное представление приложения, которое отображается на домашнем экране, когда приложение работает в фоновом режиме. Обложка позволяет взаимодействовать с приложением (например, выполнять какие-либо действия), либо просто отображать его статус.

Например:

ApplicationWindow {
    initialPage: Component { MyPage {} }
    cover: Component { MyCover {} }
}

Обложка должна предусматривать возможность масштабирования, так как её размер может изменяться в зависимости от количества приложений, запущенных в фоновом режиме. Если для обложки необходимы какие-либо действия, то их реализацию следует выполнять в контейнере CoverActionList.

Включение изменений ориентации

Приложению можно разрешить изменять ориентацию пользовательского интерфейса в соответствии с изменением ориентации устройства либо ограничить пользовательский интерфейс одной ориентацией, изменив свойство allowedOrientations.

Свойство orientation отражает текущую ориентацию пользовательского интерфейса и может быть использовано для оптимального (для текущей ориентации) расположения элементов.

Для приложений, использующих объект типа PageStack, следует предпочесть использование функциональности, экспортированной компонентом Page для поддержки нескольких ориентаций.

Работа с вырезами и закругленными углами экрана

Для правильной работы на дисплеях с вырезами и закругленными углами в ApplicationWindow имеется механизм безопасной зоны. Безопасная зона — это область экрана, в которой приложение может корректно разместиться и отображаться независимо от устройства и характеристик его дисплея. Этот механизм позволяет приложению в безопасной зоне выглядеть правильно в любой ситуации. Для новых приложений лучше выбирать полноэкранный режим displayMode, поскольку так они выглядят более естественно и красиво.

Чтобы отслеживать точные границы безопасной зоны, можно использовать свойство insets из прикрепляемого свойства SafeZoneRect.

В примере ниже показано, как работать с SafeZoneRect:

Page {
    id: page

    allowedOrientations: Orientation.All

    SilicaFlickable {
        anchors.fill: parent

       Rectangle {
           anchors {
               horizontalCenter: parent.horizontalCenter
               top: parent.top
               topMargin: SafeZoneRect.insets.top
           }
           width: 100
           height: 100

           color: "green"
       }

        Rectangle {
            anchors {
                verticalCenter: parent.verticalCenter
                left: parent.left
                leftMargin: SafeZoneRect.insets.left
            }
            width: 100
            height: 100

            color: "red"
        }
    }
}

"Пример работы с SafeZoneRect"

См. также displayMode и SafeZoneRect.

Описание свойств

allowedOrientations : enumeration

Содержит набор значений ориентаций, которые могут задавать поворот интерфейса. Значение может быть любой комбинацией из:

Orientation.Portrait;
Orientation.Landscape;
Orientation.PortraitInverted;
Orientation.LandscapeInverted.

Кроме этого, могут быть использованы следующие значения:

Orientation.PortraitMask;
Orientation.LandscapeMask;
Orientation.All.

Ориентация интерфейса пользователя управляется путём изменения значения свойства allowedOrientations. Если текущая ориентация устройства разрешена маской allowedOrientations, то при изменении ориентации устройства новая ориентация будет автоматически выбрана в качестве текущей ориентации пользовательского интерфейса.

Если текущая ориентация устройства разрешена, то при изменении свойства allowedOrientations она сразу будет выбрана в качестве ориентации интерфейса пользователя. В противном случае будет проверена следующая последовательность ориентаций относительно маски: Portrait, Landscape, LandscapeInverted, PortraitInverted, и будет выбрана первая разрешенная ориентация.

Если приложение по умолчанию должно повторять ориентацию других приложений платформы, свойство allowedOrientations может быть привязано к defaultAllowedOrientations. Следует обратить внимание, что значение defaultAllowedOrientations зависит от конфигурации устройства.

Приложение может установить свойство allowedOrientations так, чтобы ограничить набор возможных ориентаций для всех страниц в PageStack. Затем фактическая ориентация выбирается из пересечения разрешенных ориентаций для ApplicationWindow и для Page, которая является текущей вершиной стека. Если текущая страница требует ориентации, которую свойство ApplicationWindow не разрешает, то ориентация Page будет иметь приоритет.

Значение по умолчанию: Orientation.All.

См. также: orientation, defaultAllowedOrientations, deviceOrientation и Page.

background.color : color