QML-тип RenameDialog

Диалог переименования с многострочным редактором и валидацией. Подробнее....

Строка импорта:

import Sailfish.Pickers 1.0

• Список всех членов класса, включая унаследованные

Свойства

• filename : string
• invalidCharacters : var

Подробное описание

Переменная filename может использоваться для установки начального имени файла.

Пример использования:

 import QtQuick 2.2
 import Sailfish.Silica 1.0
 import Sailfish.Pickers 1.0

 ApplicationWindow {
     initialPage: Component {
         Page {
             id: page

             property string directoryPath
             property string filename

             SilicaFlickable {
                 anchors.fill: parent
                 contentHeight: column.height + Theme.paddingLarge * 2

                 Column {
                     id: column

                     width: parent.width

                     PageHeader {
                         title: "Пример выбора каталога"
                     }

                     Label {
                         text: filename ? filename : "Нет"
                     }

                     ValueButton {
                         anchors.horizontalCenter: parent.horizontalCenter
                         label: "Католог"
                         value: directoryPath ? directoryPath : "Нет"

                         onClicked: pageStack.push(renameDialog)
                     }
                 }
             }

             Component {
                 id: renameDialog

                 RenameDialog {
                     acceptDestination: folderPickerDialog
                     filename: page.filename

                     onAccepted: page.filename = filename
                 }
             }

             Component {
                 id: folderPickerDialog

                 FolderPickerDialog {
                     acceptDestination: page
                     title: "Скачать в"
                     checkLengthPath: true

                     onAccepted: directoryPath = selectedPath
                 }
             }
         }
     }
 }

Описание свойств

filename : string

Свойство содержит имя файла, который следует переименовать.

По умолчанию имя файла пустое.

invalidCharacters : var

Свойство содержит массив недопустимых символов, которых не должно быть в имени файла.

По умолчанию это символы / и \0.