FaviconExtension

Предоставляет возможность доступа к фавиконам сайта. Подробнее…

Подключение:

#include <faviconextension.h>

Диаграмма наследования для Aurora::WebView::Extensions::FaviconExtension:

Пример получения иконок сайта по различным размерам:

import QtQuick 2.0
import Sailfish.Silica 1.0
import ru.auroraos.WebView 1.0

Page {
    id: page

    property bool isAurora: true

    SilicaFlickable {
        anchors.fill: parent
        contentHeight: column.height

        Column {
            id: column

            anchors.fill: parent
            spacing: Theme.paddingLarge

            PageHeader { title: "FaviconExtension" }

            // Метки для отображения статуса
            Label { id: faviconStatus; text: "-"; font.pixelSize: 22 }
            Label { id: allFaviconStatus; text: "-"; font.pixelSize: 22 }
            Label { id: sizesLabel; text: "-"; font.pixelSize: 22 }

            // Переключение сайта
            Button {
                text: "Изменить сайт"

                onClicked: {
                    faviconStatus.text = "-"
                    allFaviconStatus.text = "-"
                    sizesLabel.text = "-"
                    console.log(webView.url)
                    webView.url = isAurora ? "https://yandex.ru" : "https://auroraos.ru"
                    isAurora = !isAurora

                }
            }

            // Получение всех размеров иконок
            Button {
                text: "Получить все размеры иконок"

                onClicked: {
                    var sizes = faviconExtension.availableSizes()
                    sizesLabel.text = sizes.join("; ")
                }
            }

            // Получение иконок 32x32
            Button {
                text: "Получить иконки 32x32"

                onClicked: {
                    // Следует обратиться к компоненту faviconExtension для получения иконок
                    var favicons = faviconExtension.favicons(Qt.size(32, 32))
                    image32.source = favicons.length > 0 ? favicons[0].base64PNGData : ""
                }
            }
            Image { id: image32 }

            // Получение иконок 48x48
            Button {
                text: "Получить иконки 48x48"

                onClicked: {
                    // Возвращается QVariantList из объектов Favicon. Соответственно, к иконкам применимы все параметры Favicon.
                    var favicons = faviconExtension.favicons(Qt.size(48, 48))
                    image48.source = favicons.length > 0 ? favicons[0].base64PNGData : ""
                }
            }
            Image { id: image48 }

            // FaviconExtension используется внутри WebView
            WebView {
                id: webView

                width: parent.width
                height: page.height - webView.y

                url: "https://auroraos.ru"

                FaviconExtension {
                    id: faviconExtension

                    onDownloaded: {
                        faviconStatus.text = "Иконки: " + downloadedCount + "/" + totalCount
                    }
                    onDownloadFinished: {
                        allFaviconStatus.text = "Все иконки доступны"
                    }
                    onDownloadStarted: {
                        faviconStatus.text = "-"
                        allFaviconStatus.text = "-"
                        sizesLabel.text = "-"
                    }
                }
            }
        }
    }
}

Сигналы

void	downloadStarted () Испускается, когда начинается загрузка фавиконов сайта. Подробнее...
void	downloaded (QSize size, int downloadedCount, int totalCount) Испускается при загрузке фавикона. Подробнее...
void	downloadFinished (int count) Испускается, когда все фавиконы текущего сайта загружены. Подробнее...

Сигналы, унаследованные от Aurora::WebView::WebViewExtension

void	webViewChanged (WebViewItem *oldItem, WebViewItem *newItem) Сигнализирует об изменении родительского элемента QuickItem. Подробнее...

Публичные функции-члены

	FaviconExtension (QQuickItem *parentWebView=Q_NULLPTR) Создаёт новый объект FaviconExtension.
	~FaviconExtension () Уничтожает объект FaviconExtension.
Q_INVOKABLE QVariantList	availableSizes () const Получает все доступные размеры фавиконов. Подробнее...
Q_INVOKABLE QVariantList	favicons (QSize size) const Получает все фавиконы с указанным размером. Подробнее...

Публичные функции, унаследованные от Aurora::WebView::WebViewExtension

WebViewExtension (QQuickItem *parent=Q_NULLPTR)

Дополнительные наследуемые члены

Защищённые функции-члены, наследованные от Aurora::WebView::WebViewExtension

void	syncEnabled (Cef::BrowserExtension *libExtension)

Защищённые атрибуты, унаследованные от Aurora::WebView::WebViewExtension

WebViewItem *

m_webView

Подробное описание

Предоставляет возможность доступа к фавиконам сайта.

Описание функций-членов

availableSizes()

Q_INVOKABLE QVariantList Aurora::WebView::Extensions::FaviconExtension::availableSizes () const

Возвращает все доступные размеры значков.

Нужно вызвать эту функцию перед запросом значков, чтобы получить список доступных размеров.

Возвращает QVariantList из значений QSize.

downloaded

void Aurora::WebView::Extensions::FaviconExtension::downloaded (QSize size, int downloadedCount, int totalCount)

signal

Испускается, когда значок загружен.

Параметры

size	Размер загруженного значка.
downloadedCount	Количество загруженных значков текущего веб-сайта.
totalCount	Общее количество значков текущего веб-сайта.

downloadFinished

void Aurora::WebView::Extensions::FaviconExtension::downloadFinished (int count)

signal

Испускается, когда все значки текущего веб-сайта загружены.

Параметры

count

Количество скачанных значков.

downloadStarted

void Aurora::WebView::Extensions::FaviconExtension::downloadStarted ()

signal

Испускается при начале загрузки значков веб-сайта.

Сигнал испускается при загрузке нового сайта и предшествует загрузке значков. Все ранее загруженные значки удаляются.

favicons()

Q_INVOKABLE QVariantList Aurora::WebView::Extensions::FaviconExtension::favicons (QSize size) const

Возвращает все значки указанного размера.

Параметры

size	Размер запрашиваемых значков.

Возвращает QVariantList из объектов Favicon.